#include <rsp.h>

#define _FETCH_REF
		
#include "video_dmem.h"
#include "mpegvideo.h"

#define _IQUANT
#define _IDCT
#define _MC
#define	_RECON
#define _DMA
#define _LOOP

/* #define _NULLTASK */
/* #define _PERFTEST */
				
	.text	TASKBASE    

mpeg_init:
		
#ifdef _NULLTASK
	j taskdone
#endif

    vxor vzero,	vzero, vzero			
    addi loop, rzero, MAX_NUM_MB
    lw   outdram, OS_TASK_OFF_DATA(tskhd)
    addi datbase, rzero, MB_BASE
    addi nextbase, rzero, MB_BASE2

#ifdef _DMA
    add  dmemaddr, rzero, datbase
    add  dramaddr, rzero, outdram
    jal  DRReq
    lw   dmasize, OS_TASK_OFF_DATA_SZ(tskhd)
    jal  DMAWait
    nop	    	
#endif
	    			
proc_mb:	   
    addi loop, loop,  -1
    lh	 mbtype, MBH_MBTYPE(datbase)

#ifdef _PERFTEST 
    ori  mbtype, rzero, MBT_FOR
/*
    ori  mbtype, mbtype, MBT_BAK
    ori  mbtype, rzero, MBT_INTRA
*/
#endif	

#ifdef _REQUANT
    andi flag,   mbtype,        MBT_REQUANT

    blez flag, dont_new_qmat
    nop

do_new_qmat:
    lh  quant,           MBH_QUANT(datbase)
    jal new_qmat
    nop

dont_new_qmat:
    nop
#endif


iq_idct:		
    jal  DMAWait	
    lh	 cbp,	MBH_CBP(datbase)

#ifdef _PERFTEST
    ori  cbp, rzero, 0x003f
#endif
	
    blez cbp, skip_mb
    andi intra,  mbtype, MBT_INTRA

#include "iquant_io.h"

    addi iq_in_dat,  datbase,	MB_DATA
    addi iq_out_dat, datbase,	MB_DATA
    addi iq_in_quant, datbase,	MBH_QUANT
    addi iq_in_cbp,  cbp,  0
    jal  iq
    addi iq_in_intra, intra, 0
		
#include "iquant_io.h" 


#include "idct_io.h"

    addi idct_in_dat,  datbase, MB_DATA
    addi idct_out_dat, datbase, MB_DATA
    jal	 idct
    addi idct_in_cbp,  cbp, 0


#include "idct_io.h"

skip_mb:
    bgtz intra, dont_mc
    nop

#ifdef _FETCH_REF

/* Local variables for reference frame fetching */
	
fetch_for:
    andi flag,   mbtype, MBT_FOR
    blez flag,   fetch_bak
    nop
	
/*  Fetch forward luminance reference block  */

#ifdef _DMA
    addi dmemaddr, rzero, MB_DATA_FREF
    lw	 dramaddr, MBS_FYPTR(datbase)
    jal  DRReq
    lw   dmasize, MBS_FYLEN(datbase)
    jal  DMAWait
    nop
	
/*  Fetch forward chrominance reference block  */
    addi dmemaddr, dmemaddr, MB_YREF_SIZE 
    lw	 dramaddr, MBS_FUVPTR(datbase)
    jal  DRReq
    lw   dmasize, MBS_FUVLEN(datbase)
    jal  DMAWait
    nop
	
#endif

fetch_bak:
    andi flag,  mbtype, MBT_BAK
    blez flag,  cont_mc
    nop

/*  Fetch backward luminance reference block  */
#ifdef _DMA
    addi dmemaddr, rzero, MB_DATA_BREF
    lw	 dramaddr, MBS_BYPTR(datbase)
    jal  DRReq
    lw   dmasize, MBS_BYLEN(datbase)
    jal  DMAWait
    nop
	
/*  Fetch backward chrominance reference block  */

    addi dmemaddr, dmemaddr, MB_YREF_SIZE 
    lw	 dramaddr, MBS_BUVPTR(datbase)
    jal  DRReq
    lw   dmasize, MBS_BUVLEN(datbase)
    jal DMAWait
    nop
	
#endif
	
cont_mc:
    andi flag,  mbtype, MBT_FOR
    blez flag, dont_for

#include "mc_io.h"

    lh   mc_in_mvx,  MBH_MVFX(datbase)
    lh   mc_in_mvy,  MBH_MVFY(datbase)
    addi mc_in_dat,  rzero, MB_DATA_FREF
    addi mc_out_dat, rzero, MB_DATA_FREF
    jal mc
    addi mc_in_blend, rzero, 0
	
    andi flag,  mbtype, MBT_BAK
    blez flag, dont_mc

both:

    lh   mc_in_mvx,  MBH_MVBX(datbase)
    lh   mc_in_mvy,  MBH_MVBY(datbase)
    addi mc_in_dat,  rzero, MB_DATA_BREF
    addi mc_out_dat, rzero, MB_DATA_FREF
    jal mc
    addi mc_in_blend, rzero, 1
		
    j   dont_mc
    nop

dont_for:

    andi flag,  mbtype, MBT_BAK
    blez flag, dont_mc

    lh   mc_in_mvx,  MBH_MVBX(datbase)
    lh   mc_in_mvy,  MBH_MVBY(datbase)
    addi mc_in_dat,  rzero, MB_DATA_BREF
    addi mc_out_dat, rzero, MB_DATA_FREF        
    jal mc
    addi mc_in_blend, rzero, 0
	
#include "mc_io.h"

#endif

	
dont_mc:
    beq  loop, rzero, do_recon
 

#ifdef _DMA
    addi dramaddr, outdram, MB_SIZE
    add  dmemaddr, rzero, nextbase
    jal  DRReq
    lw   dmasize, OS_TASK_OFF_DATA_SZ(tskhd)
#else
    nop
#endif

	
#include "recon_io.h"

do_recon:	
    addi rec_in_dat, datbase, MB_DATA
    addi rec_in_ref, rzero, MB_DATA_FREF
    addi rec_out_dat, rzero, MB_DATA_FREF
    addi rec_in_cbp, cbp, 0 
    jal	recon
    addi rec_in_intra, intra, 0
	
#include "recon_io.h"

    jal  DMAWait
    nop
		
dma_out:			
.name tmmp1, $23
.name tmmp2, $24
#ifdef _DMA
    addi  dmemaddr, rzero, MB_DATA_FREF
    lw    dramaddr, MBS_OUTYBUF(datbase)
    addi  tmmp1, $0, 336
    addi  tmmp2, $0, 15
    sll	  tmmp1, tmmp1, 20
    sll	  tmmp2, tmmp2, 12
    or	  tmmp1, tmmp1, tmmp2
    jal   DWReq
    addi  dmasize, tmmp1, 15
    jal   DMAWait

    addi  dmemaddr, dmemaddr, MB_YREF_SIZE
    lw    dramaddr, MBS_OUTUVBUF(datbase)
    addi  tmmp1, $0, 336
    addi  tmmp2, $0, 7
    sll	  tmmp1, tmmp1, 20
    sll	  tmmp2, tmmp2, 12
    or	  tmmp1, tmmp1, tmmp2
    jal   DWReq
    addi  dmasize, tmmp1, 15
    jal   DMAWait
		
    addi  dmemaddr, datbase, MB_DATA
    addi  dramaddr, outdram, MB_DATA
    jal   DWReq
    addi  dmasize, rzero, MB_DATA_SIZE
	
#endif
.unname	tmmp1
.unname tmmp2	

    beq  loop, rzero, taskdone
    addi outdram, outdram, MB_SIZE
    add  tmp, rzero, nextbase
    add	 nextbase, rzero, datbase
    j	 proc_mb
    add  datbase, rzero, tmp
	
taskdone:		
    ori  tmp, rzero, SP_SET_TASKDONE
    mtc0 tmp, SP_STATUS
    break

    nop			/* break here to output results */

    j	proc_mb
    nop

	
/* IQ		*/
#ifdef _IQUANT
	
#include "iquant_io.h"
#include "iquant.s"
#include "iquant_io.h"

#else
iq:
    jr	return
    nop

#endif

	
/* IDCT		*/
#ifdef _IDCT
	
#include "idct_io.h"
#include "idct.s"
#include "idct_io.h"

#else
idct:
    jr	return
    nop

#endif

	
/* MC		*/
#ifdef	_MC	
	
#include "mc_io.h"
#include "mc.s"
#include "mc_io.h"

#else
mc:		
    jr	return
    nop

#endif

/* Reconstruct	*/
#ifdef	_RECON

#include "recon_io.h"
#include "recon.s"
#include "recon_io.h"

#else
recon:
    jr return
    nop

#endif

/* request DMA Read access:	(get semaphore) */

DRReq:		
    mfc0 tmp, SP_RESERVED
    bne  tmp, rzero, DRReq
    # note delay slot

DRFull:	
    mfc0 tmp, DMA_FULL
    bne	 tmp, rzero, DRFull
    nop

dma_in:		
    mtc0 dmemaddr, DMA_CACHE
    mtc0 dramaddr, DMA_DRAM
    mtc0 dmasize,  DMA_READ_LENGTH
    jr   return	
    nop

/* request DMA Write access (get semaphore) */

DWReq:
    mfc0 tmp, SP_RESERVED
    bne  tmp, rzero, DWReq
    # note delay slot
	
DWFull:	
    mfc0 tmp, DMA_FULL
    bne  tmp, rzero, DWFull
    nop
			
    mtc0 dmemaddr, DMA_CACHE
    mtc0 dramaddr, DMA_DRAM
    mtc0 dmasize, DMA_WRITE_LENGTH
    jr   return
    nop

DMAWait:
    mfc0 tmp, DMA_BUSY
    bne	 tmp, rzero, DMAWait
    nop
    jr   return
    mtc0 rzero, SP_RESERVED